Uitwisselprofiel Ministerie van VWS Beleidsontwikkeling over Macro-Economische Vraagstukken en Arbeidsmarkt

Over Uitwisselprofiel Ministerie van VWS Beleidsontwikkeling over Macro-Economische Vraagstukken en Arbeidsmarkt

Publicatiedatum:
22-01-2026
Inwerkingtreding:
01-03-2026
Bekijk bron...

5.3. Wat is het aantal cliënten met een Wlz-indicatie per sector?

Concepten

Relaties

Eigenschappen

Instanties

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 5.3
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g:   <http://purl.org/ozo/onz-g#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-zorg:<http://purl.org/ozo/onz-zorg#>
8PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd:     <http://www.w3.org/2001/XMLSchema#>
10
11
12SELECT
13    ?Periode
14    (?vestiging AS ?Indeling)
15    (IF(?vestiging = "Totaal organisatie", "", SAMPLE(?zk_regio_code)) AS ?Zorgkantoorregio_code)
16    (COUNT(DISTINCT IF(?sector = onz-zorg:VV, ?client, ?unbound)) AS ?VV)
17    (COUNT(DISTINCT IF(?sector = onz-zorg:LG, ?client, ?unbound)) AS ?LG)
18    (COUNT(DISTINCT IF(?sector = onz-zorg:LVG, ?client, ?unbound)) AS ?LVG)
19    (COUNT(DISTINCT IF(?sector = onz-zorg:VG, ?client, ?unbound)) AS ?VG)
20    (COUNT(DISTINCT IF(?sector = onz-zorg:ZGAUD, ?client, ?unbound)) AS ?ZGAUD)
21    (COUNT(DISTINCT IF(?sector = onz-zorg:ZGVIS, ?client, ?unbound)) AS ?ZGVIS)
22    (COUNT(DISTINCT IF(?sector = onz-zorg:GGZ-B, ?client, ?unbound)) AS ?GGZ_B)
23    (COUNT(DISTINCT IF(?sector = onz-zorg:GGZ-W, ?client, ?unbound)) AS ?GGZ_W)
24{
25#    BIND(2024 AS ?jaar)
26    VALUES ?kw { 1 2 3 4 0 }
27
28    BIND( xsd:date(CONCAT(STR(?jaar), "-",
29                      IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01", "01-01"))))
30         )) AS ?p_start )
31    BIND( xsd:date(CONCAT(STR(?jaar), "-",
32             IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
33         )) AS ?p_eind )
34    BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
35
36    ?sector
37        a onz-zorg:LangdurigeZorgSector .
38    ?client
39        a onz-g:Human .
40
41    ?indicatie
42        a onz-zorg:WlzIndicatie ;
43        onz-g:isAbout ?client ;
44        onz-g:hasPart/onz-g:isAbout ?sector ;
45        onz-g:startDatum ?start_indicatie .
46        OPTIONAL {?indicatie onz-g:eindDatum ?eind_indicatie}
47        FILTER(?start_indicatie <= ?p_eind && ( !BOUND(?eind_indicatie) || ?eind_indicatie >= ?p_start ))
48
49    # Koppel een zorgproces aan de Wlz indicaties en locaties
50    ?zorgproces a onz-g:CureAndCareProcess ;
51                onz-g:definedBy ?indicatie ;
52                onz-g:hasPerdurantLocation/onz-g:partOf* ?locatie ;
53                onz-g:startDatum ?start_zorgproces .
54    OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces }
55    FILTER(?start_zorgproces <= ?p_eind && ( !BOUND(?eind_zorgproces) || ?eind_zorgproces >= ?p_start ))
56
57  {
58    ?locatie onz-g:partOf* ?vestiging_uri .
59    ?vestiging_uri a onz-org:Vestiging ;
60      onz-g:identifiedBy ?vest_nr ;
61      onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
62    ?vest_nr a onz-org:Vestigingsnummer ;
63      onz-g:hasDataValue ?vestiging .
64
65    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
66    ?pc_gebied onz-g:identifiedBy ?postcode ;
67      onz-g:partOf+ ?zk_regio .
68    ?zk_regio a onz-org:ZorgkantoorRegio .
69  } UNION {
70    ?locatie onz-g:partOf* ?vestiging_uri .
71    ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
72    BIND("Totaal organisatie" AS ?vestiging)
73  }
74
75  BIND(IF(BOUND(?zk_regio), STRAFTER(STR(?zk_regio), "/onz-org/"), ?unbound) AS ?zk_regio_code)
76
77}
78GROUP BY ?Periode ?vestiging ?zk_regio_code
79ORDER BY ?Periode ?vestiging ?zk_regio_code
80
Terug naar: 5.2. Wat is het aantal cliënten per financieringsstroom?